Self Shadow

An online shadow of myself

Counting Quads

| Comments

This is a DX11 followup to an earlier article on quad ‘overshading’. If you’ve already read that, then feel free to skip to the meat of this post.

Recount

As you likely know, modern GPUs shade triangles in blocks of 2x2 pixels, or quads. Consequently, redundant processing can happen along the edges where there’s partial coverage, since only some of the pixels will end up contributing to the final image. Normally this isn’t a problem, but – depending on the complexity of the pixel shader – it can significantly increase, or even dominate, the cost of rendering meshes with lots of very small or thin triangles.

Figure 1: Quad overshading, the silent performance killer

For more information, see Fabian Giesen’s post, plus his excellent series in general.

It’s hardly surprising, then, that IHVs have been advising for years to avoid triangles smaller than a certain size, but that’s somewhat at odds with game developers – artists in particular – wanting to increase visual fidelity and believability, through greater surface detail, smoother silhouettes, more complex shading, etc. (As a 3D programmer, part of my job involves the thrill of being stuck in the middle of these kinds of arguments!)

Traditionally, mesh LODs have helped to keep triangle density in check. More recently, deferred rendering methods have sidestepped a large chunk of the redundant shading work, by writing out surface attributes and then processing lighting more coherently via volumes or tiles. However, these are by no means definitive solutions, and nascent techniques such as DX11 tessellation and tile-based forward shading not only challenge the status quo, but also bring new relevancy to the problem of quad shading overhead.

Knowing about this issue is one thing, but, as they say: seeing is believing. In a previous article, I showed how to display hi-z and quad overshading on Xbox 360, via some plaform-specific tricks. That’s all well and good, but it would be great to have the same sort of visualisation on PC, built into the game editor. It would also be helpful to have some overall stats on shading efficiency, without having to link against a library (GPUPerfAPI, PerfKit) or run a separate tool.

There are several ways of reaching these modest goals, which I’ll cover next. What I’ve settled on so far is admittedly a hack: a compromise between efficiency, memory usage, correctness and simplicity. Still, it fulfils my needs so far and I hope you find it useful as well.

Going To Eleven

First, let’s restate the problem: what we want, essentially, is to count up the number of times we shade a given screen quad. The trick is to only count each shading quad once.

The way I achieved this on Xbox 360 hinged on knowing whether a given pixel was ‘alive’ or not, and then only accumulating overdraw for the first live pixel in each shading quad. As far as I’m aware, there’s no official way of detemining this on PC through standard graphics APIs, but some features of DX11 – namely Unordered Access Views (UAVs) and atomic operations – will allow us to arrive at the same result via a different route.

The right way

What I was after was an implementation that was as simple as before, involving three steps:

  • Render depth pre-pass (optional; do whatever the regular rendering path does for this)
  • Render scene (material/lighting passes) with special overdraw shader
  • Display results

A straightforward, safe option is to gather a list of triangles per screen quad, filtering by ID (a combination of SV_PrimitiveID and object ID). This filtering can be performed during the overdraw pass or as a post-process.

What’s unsatisfying with this approach is that it involves budgeting memory for the worst case, or accepting an upper bound on displayable overdraw. Whilst I can imagine that a multi-pass variation is doable, that just adds unwanted complexity to what ought to be a simple debug rendering mode.

The wrong way

So, in order to overcome these limitations, I started toying around with something a lot simpler:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
RWTexture2D<uint> primIDUAV   : register(u0);
RWTexture2D<uint> overdrawUAV : register(u1);

[earlydepthstencil]
void OverdrawPS(float4 vpos : SV_Position, uint id : SV_PrimitiveID)
{
    uint2 quad = vpos.xy*0.5;
    uint  prevID;

    InterlockedExchange(primIDUAV[quad], id, prevID);

    if (prevID != id)
        InterlockedAdd(overdrawUAV[quad], 1);
}

The intent here is to use a UAV to keep track of the current triangle per screen quad. Through InterlockedExchange, we both update the ID and use the previous state to determine if we’re the first pixel to write this ID (prevID != id). If so, we increment an overdraw counter in a second UAV. This is similar in the spirit to the Xbox 360 version, in that we’re selecting one of the live pixels in a shading quad to update the overdraw count. Finally, we can display the results in a fullscreen pass:

1
2
3
4
5
6
7
Texture2D<uint> overdrawSRV;

float4 DisplayPS(float4 vpos : SV_Position) : SV_Target
{
    uint2 quad = vpos.xy*0.5;
    return ToColour(overdrawSRV[quad]);
}

On paper, this appears to elegantly avoid the storage and complexity of the previous approach. Alas, it relies on one major, dubious assumption: that quads are shaded sequentially! In reality, GPUs process pixels in larger batches of warps/wavefronts and there’s no guarantee that UAV operations are ordered between quads – hence the name: unordered. So, during the shading of pixels in a quad for one triangle, it’s perfectly possible for another unruly triangle to stomp over the quad ID and break the whole process!

The cheat’s way

Fortunately, we can get around this issue with a few modifications. The basic idea here is to loop and use InterlockedCompareExchange to attempt to lock the screen quad:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
RWTexture2D<uint> lockUAV     : register(u0);
RWTexture2D<uint> overdrawUAV : register(u1);

[earlydepthstencil]
void OverdrawPS(float4 vpos : SV_Position, uint id : SV_PrimitiveID)
{
    uint2 quad = vpos.xy*0.5;
    uint  prevId;

    uint unlockedID = 0xffffffff;
    bool processed  = false;
    int  lockCount  = 0;

    for (int i = 0; i < 16; i++)
    {
        if (!processed)
            InterlockedCompareExchange(lockUAV[quad], unlockedID, id, prevID);

        [branch]
        if (prevID == unlockedID)
        {
            // Wait a bit, then unlock for other quads
            if (++lockCount == 2)
                InterlockedExchange(lockUAV[quad], unlockedID, prevID);
            processed = true;
        }

        if (prevID == id)
            processed = true;
    }

    if (lockCount)
        InterlockedAdd(overdrawUAV[quad], 1);
}

This leads to three outcomes for unprocessed pixels:

  • If prevID == unlockedID, then the pixel holds the lock for its shading quad
  • If prevID == id, another pixel in the shading quad holds the lock
  • Otherwise, no pixel in the shading quad holds the lock

In the first case we mark the pixel as processed and increment a lock counter. After an additional iteration, we release the lock. This ensures that pixels with the same ID see the state of the lock (second case), so that they can be filtered out. Finally, pixels that held the lock update the quad overdraw.

Ideally we’d loop until the pixel has been tagged as processed, but I haven’t had success with current NVIDIA drivers and UAV-dependent flow control, i.e.:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
[allow_uav_condition]
while (1)
{
    // ...

        if (++lockCount == 2)
        {
            InterlockedExchange(lockUAV[quad], unlockedID, prevID);
            break;
        }

    // ...

    if (prevID == id)
        break;
}

As a workaround, I’ve simply set the iteration count to a number that works well in practice across NVIDIA and AMD GPUs (those that I’ve had a chance to test, anyway).

Four, Three, Two, One

Now that we have a working system in place, it’s easy to gather other stats. For instance, although we can’t determine directly if a pixel is alive, we can count the number of live pixels in each shading quad, since Interlocked* operations are masked out for dead pixels. With this, we can tally up the number of quads with 1 to 4 live pixels in yet another UAV:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
RWTexture2D<uint> lockUAV      : register(u0);
RWTexture2D<uint> overdrawUAV  : register(u1);
RWTexture2D<uint> liveCountUAV : register(u2);
RWTexture1D<uint> liveStatsUAV : register(u3);

[earlydepthstencil]
void OverdrawPS(float4 vpos : SV_Position, uint id : SV_PrimitiveID)
{
    uint2 quad = vpos.xy*0.5;
    uint  prevID;

    uint unlockedID = 0xffffffff;
    bool processed  = false;
    int  lockCount  = 0;
    int  pixelCount = 0;

    for (int i = 0; i < 64; i++)
    {
        if (!processed)
            InterlockedCompareExchange(lockUAV[quad], unlockedID, id, prevID);

        [branch]
        if (prevID == unlockedID)
        {
            if (++lockCount == 4)
            {
                // Retrieve live pixel count (minus 1) in quad
                InterlockedAnd(liveCountUAV[quad], 0, pixelCount);

                // Unlock for other quads
                InterlockedExchange(lockUAV[quad], unlockedID, prevID);
            }
            processed = true;
        }

        if (prevID == id && !processed)
        {
            InterlockedAdd(liveCountUAV[quad], 1);
            processed = true;
        }
    }

    if (lockCount)
    {
        InterlockedAdd(overdrawUAV[quad], 1);
        InterlockedAdd(liveStatsUAV[pixelCount], 1);
    }
}

To my surprise, incrementing a 4-wide UAV didn’t lead to a massive slowdown here. That said, one can certainly use a number of buckets for intermediate results (indexed by the lower bits of the screen position, for instance), if this proves to be a problem.

With these numbers, it’s trivial to add a pie chart to the final pass:

Figure 2: Quad overdraw (dark blue = 1x, to green = 4x),
and proportion of live pixels per quad (yellow = 4, to dark red = 1)

Demolition

For your convenience, I’ve packaged things up into a simple demo. Please let me know if you hit any compatibility issues, or come up with any enhancements.

Comments